home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 4
/
FM Towns Free Software Collection 4 - Disc 1.iso
/
fb386
/
simuty
/
simuty.bas
next >
Wrap
BASIC Source File
|
1991-10-18
|
3KB
|
76 lines
1 ' save "simuty.bas",a
2 '
3 ' < 使い方 >
4 ' 1090~1100行にそれぞれ、ドライブ名とファイル名を書き込
5 ' んで下さい。(入力させる方が良かったかな?)
6 ' あとは、データディスクをセットして一丁上がり。
7 '
8 '
1000 ' シムシティ(FM-TOWNS版) MAXIS社
1010 ' 『お金を増やそう!』という、プログラム
1020 '
1030 ' 言 語 :FBHG/FBASIC386
1040 ' ファイル名:SIMUTY.BAS
1050 ' 日 付 :1990.05.08 (AM 01:26) Ver 1.0
1060 ' プログラム:炬燵猫(G-A7/住職ソフト)
1070 '
1080 '
1090 DRIVE$ = "a:" ' ドライブ名を書く
1100 FILNAM$ = "kappa" ' 都市名を書く
1110 :
1120 *MES
1130 data " "
1140 data "[ シムシティ・開発融資銀行 ]", " "
1150 data " 当行は、都市開発の政府援助を目的に設立されました。 "
1160 data " この都市開発には、政府の地方交付金と無償援助金を充てるので、"
1170 data " 費用は全て政府持ち、という訳ですな。 "
1180 data " しかしながら、有効に使って頂かないと、"
1190 data " あとで責任問題になりかねませんぞ。 " , " "
1200 data " さて、市長。いか程、御融資しましょうか。" , ""
1210 :
1220 :
1230 M$(0) = "市長、お気は確かですか? もう1度、お聞きしますよ。"
1240 M$(1) = "御冗談を・・・難行・苦行のつもりですか? やめましょう。"
1250 M$(2) = "市長、欲張りすぎちゃいけません。もう少しお考えを。"
1260 M$(3) = "分かりました。御融資致しましょう。"
1270 M$(4) = "よろしいですね。(y/n)= "
1280 M$(5) = "市長の御健闘をお祈り致しております。(終了しました)"
1290 :
1300 '
1310 :
1320 cls
1330 print "ドライブ" + akcnv$( DRIVE$ ) + "に、";
1340 print akcnv$(FILNAM$) + "のファイルのあるディスクをセットして下さい。"
1350 print "準備できましたら、スペースキーを押して下さい。"
1360 :
1370 while ( inkey$<>"" ) : wend : while ( input$(1)<>" " ) : wend
1380 while ( inkey$<>"" ) : wend
1390 :
1400 open "R" , #1 , DRIVE$ + "(1)" + FILNAM$ + ".cty"
1410 field #1 , 1 as DAT$
1420 :
1430 restore *MES : A$ = " " : while ( A$<>"" ) : read A$ : print A$ : wend
1440 :
1450 *INP_MONEY
1460 print : input "御希望の金額をどうぞ=" , MONEY$
1470 MONEY# = val( MONEY$ )
1480 if MONEY# = 0 then print M$(0) : goto *INP_MONEY
1490 if MONEY# < 0 then print M$(1) : close : end
1500 if MONEY# > 10000000# then print M$(2) : close : end
1510 print M$(3)
1520 print akcnv$( str$( MONEY# ) ) ; "ドル ですね。"
1530 print M$(4) ; : YN$ = input$(1) : print YN$
1540 if YN$<>"y" and YN$<>"Y" then *INP_MONEY
1550 :
1560 for I=0 to 3
1570 M1# = int( MONEY# / 256 )
1580 M2# = MONEY# - M1# * 256
1590 MONEY# = ( MONEY# - M2# ) / 256
1600 MBYTE(I) = M2#
1610 lset DAT$ = chr$( MBYTE(I) )
1620 put #1 , &HC27 - I + 1 ' high から lowへ
1630 next
1640 :
1650 close : print M$(5)
1660 end